#NoEnv  			; Recommended for performance and compatibility with future AutoHotkey releases.
#Warn  				; Enable warnings to assist with detecting common errors.
SendMode Input  		; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% 	; Ensures a consistent starting directory.
#SingleInstance force		; Replaces script (Reloads).
#Persistent			; to make it run indefinitely
#IfWinActive ahk_exe S:\MuseScore 3.6 portable\MuseScorePortable\App\MuseScore\bin\MuseScore3.exe	; Enables Hotkeys when MuseScore3 Window is Active
#Include Coordinates.ahk	; All coordinates are managed in this external file
				; The Include directive causes the script to behave as though
				; the specified file's contents are present at this exact position


; Replace the path S:\etc. with your location of MuseScore3.exe

; Increase/Decrease note duration dotted. Press N and start inputtting notes.
; WheelDown is toward you, Wheelup is away from you.
; To correct notes, input at the wrong pitch input the right one and click on the wrong one.
; To remove undesired ties across measures: right click on the first beat
; and change the duration with the wheel.  Remove notes in chords bij clicking on them.
; Chords across barlines, only using Mouse and wheel are possible
; but MuseScore's native method works much faster in this case.
; FREE CANVAS


; https://musescore.org/en/node/312544 - Finale-style Speedy Entry

~[ & F11::
CoordMode, Tooltip, Screen
Tooltip, F11  Wheel Input, ToolT_F11_X, 0, 1		; tooltip (1) Wheel Input
Return

~] & F11::
MsgBox, 4132, Wheel Input, Are you sure you want to exit?
IfMsgBox, Yes
ExitApp
Return

~[ & -::
MsgBox, 4096 , F11: Wheel Note Input      [ + -,
(
Note Input toggle		N
Note Input toggle		X-Button2
Increase duration		\⁰ + WheelUp
Decrease duration		\⁰ + WheelDown
To next note or rest	\⁰ + RButton
To previous note or rest	\⁰ + LButton
Create rest #		\⁰ + MButton
Create tie		\⁰ + Z
Input a note		Leftclick
Delete a note		Rightclick
Semitone higher		X-Button1 + WheelUp
Semitone lower		X-Button1 + WheelDown

# Switches Note Input on

Exit 			] + F11
)
Return

; about key SC056
; Some computer keyboards have this extra key. Sometimes conveniently at the extreme left between Shift and Z.
; The key has the ScanCode 056 and produces a backslash \ when you type. (as a second backslash/pipe key)
; The normal backslash \ is used in many hotkey commands. It is the key near Return.
; This second backslash key is ONLY used in the commands of this macrogroup F11.
; Maybe your kbd has another special key between Shift and Z.
; You find info about the scancode of keys in the AHK helpfile: List of Keys -> Special Keys
; If your comp.kbd. lacks this key: substitute it by another prefix key.
; For instance a free or 'liberated' key like T, U, Y or some other prefix key of which
; the combination with the L/R//M mousebuttons and Z is not already in use.

; You can inspect the scancode of a key by clicking the AHK icon in the systemtray.
; View -> Key history and system info


XButton1 & WheelUp::Send {up}		; wheel away from you, semitone higher

XButton1 & WheelDown::Send {down}	; wheel towards you, semitone lower

XButton2::Send n

~SC056 & WheelUp::Send +w		; increase note duration dotted

~SC056 & WheelDown::Send +q		; decrease note duration dotted

~SC056 & LButton::Send {left}		; to previous note or rest

~SC056 & RButton::Send {right}		; to next note or rest

~SC056 & MButton::Send 0		; enters note input mode and creates rest

~SC056 & z::Send +{=}			; creates tie


/*
; https://www.autohotkey.com/boards/viewtopic.php?t=24787
XButton1 up::  ; up is required in this case.
if (A_PriorKey = "XButton1")
    Send {XButton1}	
return
XButton1 & WheelUp:: Send {Volume_Up 2}	
XButton1 & WheelDown:: Send {Volume_Down 2}	

#IfWinexist WHATEVER 
~Xbutton1::
*/